Nom

swap_handles — Permute deux handle dans la hiérarchie graphique.

Séquence d'appel

swap_handle( handle1, handle2 )

Paramètres

handle1

premier handle de la permutation.

handle2

second handle de la permutation.

Description

La fonction swap_handles permet de permuter deux handles dans la hierarchie graphique. Le premier prend la place du second et inversement.

Comme tous les handles graphiques ne sont pas compatibles entre eux, il existe des restrictions quant à   l'utilisation de la routine. Il est par exemple impossible de permuter un handle polyline et un handle axes, ils ne seraient alors plus compatible avec leur nouveaux parents. Pour plus d'information à   ce sujet, on peut se reporter à   la page graphics_entities .

La routine peut-être utilisée pour modifier les indices des enfants d'un handle.

Exemples

 
//------------------//
//  Premier exemple //
//------------------//

// creation d'un rectangle
xrect( 0.5, 0.5,0.5,0.5) ;
rect = gce() ;

// creation d'un cercle
xarc( 0.5, 0.5, 0.5, 0.5, 0, 64 * 360 ) ;
circle = gce() ;

// creation d'une flèche
xpoly([0,1],[0,1]) ;
arrow = gce() ;
arrow.polyline_style = 4 ;
arrow.arrow_size_factor = 4 ;

// affichage de la liste des enfants
axes = gca()  ;
axes.children

// modification de l'odre des enfants
swap_handles( rect, arrow ) ;
swap_handles( arrow, circle ) ;

// affichage du nouvel ordre
axes.children

//-------------------//
//  Deuxième exemple //
//-------------------//

// creation de deux fenêtres
plot2d ;
axes1 = gca() ;

scf() ;
fec ;
axes2 = gca() ;

// parmutation de leurs axes respectifs
// Onpeut noter que les axes héritent de la color map de leur nouvelle fenêtre.
swap_handles( axes1, axes2 ) ;
 

Voir Aussi

graphics_entities , copy , delete , relocate_handle

Auteurs

Jean-Baptiste Silvy