barhomogenize — homogeneise toutes les barres contenues dans les axes courrants de travail
barhomogenize() barhomogenize([h[,'style'[,'width']]])
un pointeur sur les axes, (par defaut: h=gca() ).
une chaine, 'grouped' ou 'stacked' (par defaut: 'grouped').
(optionnel), un scalaire, qui defini l'epaisseur des barres (un pourcentage de l'epaisseur maximun autorisé pour une barre) (par defaut: width=0.8, i.e 80%).
S'il y a plusieurs appels à la fonction bar, la fonction
barhomogenize permet d'homogeneiser l'epaisseur et le style
de toutes les barres (i.e de type polyline_style 6) contenues
dans les axes de travail. Ces barres doivent avoir les meme abscisses (x
data).
barhomogenize( ) : prends les valeurs suivantes par
defaut: h=gca(), width=0.8, style='grouped'.
barhomogenize(h,...) : definit les axes courants dans
lesquels le dessin sera réalisé.
barhomogenize(...,width,...) : definit l'epaisseur des
barres, en pourcentage (generallement : 0<width<=1).
barhomogenize(...,style,...) : definit la façon dont les
barres sont positionnées les unes par rapport aux autres. L'option style
fixée à 'grouped' permet de centrer les polylines par rapport à leurs
abscisses, et l'option style fixée à 'stacked' permet de les empiler.
// Premier exemple : creation d'une barre jaune(i.e une polyline de type polyline_style=6) et de 3 barres(i.e 3 polylines de type polyline_style=6)
subplot(2,3,1)
xtitle('ex1: creation of 1 yellow bar and 3 bars')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);
// homogeneisation des 4 barres avec l'option style fixée à 'grouped' (par défaut)
subplot(2,3,2)
xtitle('grouped homogenisation')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);
barhomogenize();
// homogeneisation des 4 barres avec l'option style fixée à 'stacked'
subplot(2,3,3)
xtitle('stacked homogenisation')
x=1:3; y1=1:3; y2=[4 3 5;6 7 8;9 10 11];
bar(x,y1,'yellow');bar(x,y2);
barhomogenize('stacked',1);
// Deuxieme exemple
// creation d'une barre (i.e une polyline de type polyline_style=6, avec un appel à la fonction bar) et deux polylines (i.e 2 polylines de type polyline_style=1, avec un appel à la fonction plot)
subplot(2,3,4)
xtitle('ex2: creation of 1 bar and 2 polylines')
x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)
// modification du type polyline_style à 6 de la deuxieme polyline construite par plot (cette polyline devient une barre)
subplot(2,3,5)
xtitle('transformation of the second polyline to bar')
x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)
e=gce(); e2=e.children(2); e2.polyline_style=6;
// homogeneisation de la première barre (construite par appel à la fonction bar) et de la deuxieme barre (issue de la modification).
subplot(2,3,6)
xtitle('grouped homogenisation')
x=1:10; y=sin(x)/2;
bar(x,y,'red')
x1=1:10;y1=[sin(x);cos(x)]
plot(x1,y1)
e=gce(); e2=e.children(2); e2.polyline_style=6;
barhomogenize();
// change the style and the width
//barhomogenize('stacked',0.5);
//barhomogenize('stacked',1);